Đã trả lời Xin cách lưu data của List View

Mã (AutoIt):

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Fantasizzz", 283, 217, 192, 124)
$ListView1 = GUICtrlCreateListView("ID|Name1|Name2|Name3", 16, 48, 250, 150)
$Button1 = GUICtrlCreateButton("Add", 16, 8, 55, 25)
$Button2 = GUICtrlCreateButton("Save", 75, 8, 55, 25)
$Button3 = GUICtrlCreateButton("Delete All", 195, 8, 72, 25)
$Button4 = GUICtrlCreateButton("Load", 135, 8, 55, 25)
GUISetState(@SW_SHOW)
Local $number=0

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            Add()
        Case $Button2
            Save()
        Case $Button3
            Delete()
        Case $Button4
            Load()
    EndSwitch
WEnd

Func Add()
    GUICtrlCreateListViewItem($number&'|Item1|Item2|Item3',$ListView1)
    $number+=1
EndFunc

Func Save()
    FileDelete(@ScriptDir&'\Test.txt')
    $list_count = _GUICtrlListView_GetItemCount ($ListView1)
    For $i=0 To $list_count-1
        _GUICtrlListView_SetItemSelected($ListView1,$i)
        $Read = _GUICtrlListView_GetItemTextArray($ListView1)
        FileWriteLine(@ScriptDir&'\Test.txt',$Read[1]&'|'&$Read[2]&'|'&$Read[3]&'|'&$Read[4])
    Next
EndFunc

Func Delete()
    _GUICtrlListView_DeleteAllItems($ListView1)
    $number = 0
EndFunc

Func Load()
    $file_read = FileReadToArray(@ScriptDir&'\Test.txt')
    $Read_line = UBound($file_read)
    For $i=0 To $Read_line-1
        GUICtrlCreateListViewItem($file_read[$i],$ListView1)
    Next
EndFunc