Hỏi đáp [Solved] Xin code tạo GUI và update thông tin từ GUI vào file txt

Mã (AutoIt):

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>

$FileOption = @ScriptDir & '\NET.ini'
If Not FileExists($FileOption) Then FileOpen($FileOption, 2 + 128)
$optNAME = IniRead($FileOption, '1', 'NAME', '')
$optPORT = IniRead($FileOption, '1', 'PORT', '')
$optCOMMENT = IniRead($FileOption, '1', 'COMMENT', '')
$optIP1 = IniRead($FileOption, '2', 'IP1', '0.0.0.0')
$optIP2 = IniRead($FileOption, '2', 'IP2', '0.0.0.0')

$Form = GUICreate("GUI", 316, 235, 192, 114)
GUICtrlCreateLabel("NAME", 8, 18, 36, 17)
$InputNAME = GUICtrlCreateInput($optNAME, 80, 16, 225, 21)
GUICtrlCreateLabel("PORT", 8, 51, 36, 17)
$InputPORT = GUICtrlCreateInput($optPORT, 80, 48, 225, 21)
GUICtrlCreateLabel("COMMENT", 8, 84, 55, 17)
$InputCOMMENT = GUICtrlCreateInput($optCOMMENT, 80, 80, 225, 21)
$IPAddress1 = _GUICtrlIpAddress_Create($Form, 80, 112, 169, 21)
_GUICtrlIpAddress_Set($IPAddress1, $optIP1)
$IPAddress2 = _GUICtrlIpAddress_Create($Form, 80, 144, 169, 21)
_GUICtrlIpAddress_Set($IPAddress2, $optIP2)
$Input1 = GUICtrlCreateInput("", 256, 112, 49, 21)
$Input2 = GUICtrlCreateInput("", 256, 144, 49, 21)
$ButtonCLEAN = GUICtrlCreateButton("Xoá IP", 8, 112, 65, 54)
$ButtonOK = GUICtrlCreateButton("Đồng ý", 8, 184, 297, 41)
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $ButtonOK
            $optNAME = GUICtrlRead($InputNAME)
            IniWrite($FileOption, '1', 'NAME', $optNAME)
            $optPORT = GUICtrlRead($InputPORT)
            IniWrite($FileOption, '1', 'PORT', $optPORT)
            $optCOMMENT = GUICtrlRead($InputCOMMENT)
            IniWrite($FileOption, '1', 'COMMENT', $optCOMMENT)
            $IP1 = _GUICtrlIpAddress_Get($IPAddress1)
            IniWrite($FileOption, '2', 'IP1', $IP1)
            $IP2 = _GUICtrlIpAddress_Get($IPAddress2)
            IniWrite($FileOption, '2', 'IP2', $IP2)
        Case $ButtonCLEAN
            _GUICtrlIpAddress_Set($IPAddress1, '...')
            _GUICtrlIpAddress_Set($IPAddress2, '...')
    EndSwitch
WEnd

 

À, tại thấy thým để 2 hàng IP nên tưởng có 2 cái kaka.

 

Mã (AutoIt):

#include <GUIConstantsEx.au3>
#include <GuiIPAddress.au3>
#include <WindowsConstants.au3>

$FileOption = @ScriptDir & '\NET.txt'
If Not FileExists($FileOption) Then $hOpen = FileOpen($FileOption, 2 + 128)

$sOption = _TXT_Startup($FileOption)

$optNAME = _TXT_Read($sOption, 'NAME')
$optPORT = _TXT_Read($sOption, 'PORT')
$optCOMMENT = _TXT_Read($sOption, 'COMMENT')
$optIP = _TXT_Read($sOption, 'IP')
$optIP = StringSplit($optIP, ':', 2)
If UBound($optIP) = 1 Then Local $optIP[2]

$Form = GUICreate("GUI", 316, 200, 192, 114)
GUICtrlCreateLabel("NAME", 8, 18, 36, 17)
$InputNAME = GUICtrlCreateInput($optNAME, 80, 16, 225, 21)
GUICtrlCreateLabel("PORT", 8, 51, 36, 17)
$InputPORT = GUICtrlCreateInput($optPORT, 80, 48, 225, 21)
GUICtrlCreateLabel("COMMENT", 8, 84, 55, 17)
$InputCOMMENT = GUICtrlCreateInput($optCOMMENT, 80, 80, 225, 21)
$IPAddress = GUICtrlCreateInput($optIP[0], 80, 112, 169, 21)
GUICtrlCreateLabel(":", 251, 113, 5, 17)
GUICtrlSetFont(-1, 11, 600)
$InputPORT2 = GUICtrlCreateInput($optIP[1], 256, 112, 49, 21)
$ButtonCLEAN = GUICtrlCreateButton("Xoá IP", 8, 112, 65, 21)
$ButtonOK = GUICtrlCreateButton("Đồng ý", 8, 144, 297, 41)
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
        Case $ButtonOK
            $optNAME = GUICtrlRead($InputNAME)
            _TXT_Write($sOption, 'NAME', $optNAME)
            ;-----------------------------------------------
            $optPORT = GUICtrlRead($InputPORT)
            _TXT_Write($sOption, 'PORT', $optPORT)
            ;-----------------------------------------------
            $optCOMMENT = GUICtrlRead($InputCOMMENT)
            _TXT_Write($sOption, 'COMMENT', $optCOMMENT)
            ;-----------------------------------------------
            $IP = GUICtrlRead($IPAddress)
            $PORT2 = GUICtrlRead($InputPORT2)
            _TXT_Write($sOption, 'IP', $IP & ':' & $PORT2)
            ;-----------------------------------------------
            _TXT_SaveFile($FileOption, $sOption)

        Case $ButtonCLEAN
            GUICtrlSetData($IPAddress, '')
            GUICtrlSetData($InputPORT2, '')
            _TXT_Write($sOption, 'IP', '')
            _TXT_SaveFile($FileOption, $sOption)
    EndSwitch
WEnd

Func _TXT_Startup($sPath)
    $hOpen = FileOpen($sPath, 128)
    $hRead = FileRead($hOpen)
    FileClose($hOpen)
    Return $hRead
EndFunc

Func _TXT_SaveFile($sPath, $sData)
    $hOpen = FileOpen($sPath, 2 + 128)
    FileWrite($hOpen, $sData)
    FileClose($hOpen)
EndFunc

Func _TXT_KeyExist($sData, $_vKey)
    Return StringRegExp($sData, '(?m)^\Q' & $_vKey & ' = \E') <> 0
EndFunc

Func _TXT_Read($sData, $_vKey, $sValueReturn = '')
    Local $iRead = StringRegExp($sData, '(?m)^\Q' & $_vKey & ' = \E(.*?)$', 1)
    If @error Then Return SetError(1, 0, $sValueReturn)
    Return $iRead[0]
EndFunc

Func _TXT_Write(ByRef $sData, $_vKey, $_sValue, $_addStartData = 0)
    $sData = StringRegExpReplace($sData, '(?m)(^\Q' & $_vKey & ' = \E)(.*)$', '${1}' & StringReplace($_sValue, '\', '\\', 0, 1), 1)
    If Not @extended Then
        If $_addStartData = 1 Then
            $sData = $_vKey & ' = ' & $_sValue & @CRLF & $sData
        Else
            $sData &= @CRLF & $_vKey & ' = ' & $_sValue
        EndIf
    EndIf
EndFunc