AutoHotKey [Hướng dẫn] Cách tạo một auto click không chiếm chuột đơn giản

romanno1 · 20/3/20

Hay quá bạn ơi.
cảm ơn bạn nhiều

congdv868 · 21/3/20

sao minh chon f3 ko chay nhi

Nguyễn Tiến Vũ · 22/3/20

hay

Cu_vo · 23/3/20

Cám ơn bạn nhé !

Yashiori · 24/3/20

Cám ơn bạn nhiều

anhemnhulz · 24/3/20

Cảm ơn bạn

quachquesh · 28/3/20

cảm ơn bạn

thangcddtt · 31/3/20

bai viet rat hay

thangdpybpro · 1/4/20

Cảm ơn b

thangdpybpro · 1/4/20

Làm sao để build ra file exe được vậy mọi người,mình coppy vào build ra toàn báo lỗi,mình chỉ muốn chỉnh sửa chút hotkey cho phù hợp

thaiprovip · 2/4/20

Cảm ơn bạn nha

nongminh · 3/4/20

Milli Master nói: ↑

A/ LỜI NÓI ĐẦU

Mình chỉ mới tìm hiểu về autohotkey vừa mới đây (cũng được 1 năm), với lại mình cũng không phải là dân lập trình chỉ là thèn cu cấp 3 đam mê rồi tập tành code thôi, nên sẽ có một số cái chưa chính xác và không đạt chuẩn lắm, mong các bạn thông cảm :p. Mình thấy ngôn ngữ này khá dễ học mà ít mem quá nên làm bài này để kéo thêm mem .

B/ CHUẨN BỊ

Đầu tiên thì các bạn phải có một số kiến thức cơ bản về autohotkey của bác @kakanet ở đây, mà không cũng được từ từ rồi quen, đang cần số lượng .
Những lệnh chính mà mình sử dụng để code: ControlClick, Gui và các hàm liên quan đến listview.
Chương trình dùng ControlClick nên có ưu điểm là click không chiếm chuột, cửa sổ cần click đang bị che bởi cửa sổ khác hay là bị thay đổi vị trí ban đầu thì vẫn có thể click một cách chính xác.

B/ TIẾN HÀNH CODE

PHẦN 1:
CLICK VÀO ĐÂY ĐỂ XEM PHẦN TIẾP THEO

Đầu tiên thì mình tạo một cái gui nho nhỏ gồm cái combox để tùy chọn các kiểu click, một editbox lưu thời gian delay, một cái listview để lưu thao tác và ba cái button điều khiển. Rồi sau đó gắn label, var cho các control. Có các hotkey như F2: thêm dữ liệu vào listview, F3: chạy auto, F4: dừng auto.

Mã (Autohotkey):

#NoEnv
#SingleInstance Force
CoordMode Mouse,Window
SetControlDelay -1
;Xem file help để hiểu thêm mấy dòng trên này

playing:=0

Gui,+Alwaysontop
Gui Add, Text, x16 y8 w52 h23 +0x200 , Kiểu click:
Gui Add, DropDownList, x80 y16 w120 vModeClick, Left||Middle|Right
Gui Add, Text, x224 y16 w34 h23 +0x200, Delay:
Gui Add, Edit, x264 y16 w120 h21 vDelayTime number,100
Gui Add, ListView, x16 y56 w391 h150, X|Y|Kiểu Click|Delay|Window
Gui Add, Button, x152 y224 w80 h23 gRunAuto , Chạy (F3)
Gui Add, Button, x240 y224 w80 h23 gStopAuto , Dừng (F4)
Gui Add, Button, x328 y224 w80 h23 gClearList, Xóa (Ctrl+Del)
Gui Show, , Auto Clicker
Return

F3::goto,RunAuto
F4::goto,StopAuto
^Delete::goto,ClearList

RunAuto:

return

StopAuto:

return

ClearList:

return

GuiEscape:
GuiClose:
ExitApp

Đầu tiên thì xử lí cái phần thêm dữ liệu vào listview trước. Mình sử dụng lệnh MouseGetPos để lấy dữ liệu và hàm LV_Add() để thêm. Dữ liệu cần thêm là X|Y|Kiểu Click|Delay|Window

Mã (Autohotkey):

F2::
if playing ; nếu đang chạy auto thì không lưu vào listview
return
Gui,Submit,Nohide ; lưu dữ liệu của các control vào biến
MouseGetPos,,,WinHWND ; Lấy HWND của cửa sổ
WinActivate,ahk_id %WinHWND%
MouseGetPos,X,Y ; Lấy vị trí x, y
LV_Add("",X,Y,ModeClick,DelayTime,WinHWND)
LV_ModifyCol(1)
LV_ModifyCol(2)
;2 dòng trên là chỉnh cho cột 1,2 cho ngay
return

Thêm xong rồi thì tới phần xóa nha. Mình dùng LV_Delete().

Mã (AutoIt):

ClearList:
if playing ; đang chạy thì không được xóa
return
LV_Delete() ; xóa toàn bộ nội dung trong listview
return

Được bây giờ tới phần đọc listview rồi chạy auto đây. Mình dùng LV_GetText() để lấy dữ liệu rồi dùng ControlClick.

Mã (Autohotkey):

RunAuto:
if (LV_GetCount()=0) ;nếu không có gì trong listview thì không chạy code bên dưới
return
playing:=1 ; đang chạy auto
; Dùng vòng lặp để lấy thông tin từ listview rồi thực hiện click tuần tự
Loop % LV_GetCount() ; lấy tất cả cột của listview
{ ;tạo vòng lặp lấy dữ liệu của listview X|Y|Kiểu click|Delay|Window sau đó thực hiện click
if Stop ; dòng này để dừng auto
break
Index:=A_Index
Loop % LV_GetCount("Col") ; lấy dữ liệu của từng hàng
LV_GetText(Data_%A_Index%,Index,A_Index)
Sleep,% Data_4
ControlClick,x%Data_1% y%Data_2%,ahk_id %Data_5%,,%Data_3%,,NA Pos ;thực hiện click
}
;chạy xong thì dừng thôi
stop:=0
playing:=0 ;
return

Tiếp theo là tới phần dừng auto, dễ thôi đặt biến stop là 1

Mã (Autohotkey):

StopAuto:
if not playing ; dừng rồi dừng chi nữa :)
return
Stop:=1
playing:=0
return

Một điều quan trọng nữa là để chạy được hầu hết các cửa sổ bạn phải cho nó chạy với quyền admin. Đặt RequireAdmin() lên đầu

Mã (Autohotkey):

RequireAdmin()
{
CommandLine := DllCall("GetCommandLine", "Str")

If !(A_IsAdmin || RegExMatch(CommandLine, " /restart(?!\S)")) {
Try {
If (A_IsCompiled) {
Run *RunAs "%A_ScriptFullPath%" /restart
} Else {
Run *RunAs "%A_AhkPath%" /restart "%A_ScriptFullPath%"
}
}
ExitApp
}
}

Bạn nào muốn xem code hoàn chỉnh thì nhấn like nha
Code dưới này hơi khác với phần hướng dẫn ở trên do dạo này mình rất bận mà cũng muốn nâng cấp cái code này. Khi nào rảnh thì mình sẽ hướng dẫn :p
***Nội dung ẩn không thể được trích dẫn.***

Thế thôi bài hướng dẫn đến đây là hết. Lần sau mình thực hiện các bước tiếp theo để hoàn thiện code, hẹn gặp lại các bạn vào các phần tiếp theo .
CLICK VÀO ĐÂY ĐỂ XEM PHẦN TIẾP THEO
Nhấp vào để mở rộng

thuonghttt · 3/4/20

Milli Master nói: ↑

CLICK VÀO ĐÂY ĐỂ XEM PHẦN TRƯỚC
PHẦN 2:
Ở phần tiếp theo này (có thể là phần cuối) mình sẽ thêm vài ba chức năng (số lần chạy, gửi phím, lưu và mở) và nâng cấp code ở phần trước.
Đầu tiên là phần giao diện có chút thay đổi

Mã (Autohotkey):

#NoEnv
#NoTrayIcon
#SingleInstance Off
playing:=0
RowNumber = 0
CoordMode Mouse,Window
SetBatchLines,-1
; Cái này là cho phần gửi phím
SetKeyDelay,10,10
; Cái này cho phần lưu
FileEncoding,UTF-8
Opt:=[]

Gui +Alwaysontop +hwndhGui
Gui Add, Text, x16 y8, Hành động:
Gui Add, DropDownList, x81 y5 w120 vModeClick, Left||Middle|Right
Gui Add, Text, x215 y8 ,Delay:
Gui Add, Edit, x250 y5 w120 h21 vDelayTime number,100
Gui Add, Text, x374 y11 ,(ms)
Gui Add, Text, x16 y34 w60 h23 +0x200, Gửi phím:
Gui Add, Edit, x81 y36 w120 h21 vSendKey,
Gui Add, CheckBox, x215 y35 w120 h23 vIsCtrlSend Checked, Control Send
Gui Add, Text, x16 y64 w60 h23 +0x200, Số lần chạy: ; Đặt 0 để chạy vô hạn lần
Gui Add, Edit, x81 y66 w65 h21 number vtimes,
Gui Add, UpDown, x128 y66 w18 h21, 1
Gui Add, ListView, x16 y96 w391 h150 vMyListView, X|Y|Hành động|Gửi phím|Control Send|Delay|Cửa sổ
Gui,Add,StatusBar
SB_SetText("Kiếm gì cho tui làm đê :(",1)
SB_SetIcon("Shell32.dll", 44,1)
Gui Add, Button, x152 y258 w80 h23 gRunAuto , Chạy (F3)
Gui Add, Button, x240 y258 w80 h23 gStopAuto , Dừng (F4)
Gui Add, Button, x328 y258 w80 h23 gDellList, Xóa
Gui Show, ,Simple Auto Clicker

; Cái này là phần menu chuột phải vào listview
Menu, MyContextMenu, Add, Xóa, DellList
Menu, MyContextMenu, Icon, Xóa,shell32.dll,132
Menu, MyContextMenu, Add, Xóa tất cả, DellList
Menu, MyContextMenu, Icon, Xóa tất cả,shell32.dll,272
Menu, MyContextMenu, Add,
Menu, MyContextMenu, Add, Mở..., File
Menu MyContextMenu, Icon, Mở..., shell32.dll, 4
Menu, MyContextMenu, Add, Lưu, File
Menu MyContextMenu, Icon, Lưu, shell32.dll, 259

Return

Ở trên bạn có thấy là có phần menu, vì thế mình xử lý nó trước nha
Đầu tiên là cho cái menu nó hiện khi chuột phải

Mã (Autohotkey):

GuiContextMenu:

if A_GuiControl <> MyListView
return
Menu, MyContextMenu, Show, %A_GuiX%, %A_GuiY%
return

Được roài, giờ tiếp đến phần xóa nội dung trong listview

Mã (Autohotkey):

DellList:

; Đang chạy thì không đc xóa
if playing
return
; Cái này là bấm nút xóa trên gui
if (A_GuiControl="Xóa")
LV_Delete()
; Khi click vào menu "xóa"
else if (A_ThisMenuItem="Xóa")

else if (A_ThisMenuItem="Xóa")
{
Loop
{
RowNumber := LV_GetNext(RowNumber-1)
if not RowNumber
break
LV_Delete(RowNumber)
}
}
else
LV_Delete()
return

Okê roài, giờ mới khổ. Giờ xử lý phần mở với lưu trước rồi kết nối nó lại nha

Mã (Autohotkey):

Save:
if !LV_GetCount()
{
MsgBox, 262144, ,Có gì đâu mà lưu ta ??
return
}
SplitPath,DirFile,FileName
; Nếu người dùng không bỏ đuôi vào file thì mình thêm vào (sac = Simple Auto Clicker)
IfNotInString,FileName,.
FileName.=.sac
; Nếu đã có file tên giống vậy trước đó thì xóa đi
if FileExist(DirFile)
FileDelete,% DirFile
; Lấy dữ liệu từ listview
ControlGet, Items, List, , SysListView321, ahk_id %hGui%
; Ghi vào tệp
FileAppend,% Items,% FileName
MsgBox, 262208, ,Đã lưu
SB_SetText("Trạng thái: Đã lưu",1)
return

Open:
; Cái này khỏi nói nhá
if LV_GetCount()
MsgBox, 262177, ,Hành động này sẽ xóa toàn bộ dữ liệu bạn lưu trước đó. Bạn chắc chứ?
IfMsgBox,Cancel
return
LV_Delete()
; Dùng vòng lặp đọc từng dòng sau đó lưu vào listview
Loop,Read,% DirFile
LV_Add("",StrSplit(A_LoopReadLine,A_Tab)*)
LV_ModifyCol(1)
LV_ModifyCol(2)
SB_SetText("Trạng thái: Đã mở",1)
return

Phù, uống tý nước đi vài vòng rồi tiếp nhá. Giờ thì kết nối phần lưu, mở vào menu chuột phải

Mã (Autohotkey):

File:

Gui +OwnDialogs
(A_ThisMenuItem="Lưu") ? Opt:=["S18","Lưu","Save.sac"] : Opt:=["3","Mở"]
; Mở hộp thoại mở hoặc lưu
FileSelectFile,DirFile,% Opt[1],% Opt[3],% Opt[2],Simple Auto Clicker (*.sac)
if ErrorLevel
return
if (A_ThisMenuItem="Lưu")
gosub,Save
else
gosub,Open
return

Thêm cái phần kéo thả file đã lưu nữa là xong

Mã (Autohotkey):

GuiDropFiles:
DirFile:=A_GuiEvent
gosub,Open
return

Rồi, quá ngon luôn. Tiếp theo là mình sẽ chỉnh sửa phần thêm nội dung vào cái listview

Mã (Autohotkey):

F2::

; Không ghi khi đang auto
if playing
return
; Lưu mấy nội dung của mấy cái control vào biến
Gui,Submit,Nohide
; Quá trình lấy cửa sổ khá mất thời gian nên khóa di chuột tránh người dùng di tùm lum gây sai sót
BlockInput,MouseMove
MouseGetPos,,,WinHWND
WinGetTitle,WinTitle,ahk_id %WinHWND%
WinGetClass,WinClass,ahk_id %WinHWND%
; Phải activate lên mới lấy đc chính xác vị trí click
WinActivate,ahk_id %WinHWND%
WinWaitActive,ahk_id %WinHWND%
MouseGetPos,X,Y
BlockInput,MouseMoveOff
LV_Add("",X,Y,ModeClick,SendKey,IsCtrlSend,DelayTime,WinTitle " ahk_class " WinClass)
; Canh cột 1,2 cho ngay lại
LV_ModifyCol(1)
LV_ModifyCol(2)
return

Mình thêm một hàm vô cùng quan trọng thay thế lệnh Sleep sẵn có. Nó rất quan trọng trong phần dừng auto. Vì khi dùng lệnh Sleep sẵn có thì khi mình đã bấm dừng rồi nhưng phải đợi hết thời gian trong Sleep thì vòng lặp ở phần auto mới thực sự dừng.

Mã (Autohotkey):

Delay(time,ByRef cancel) {
start:=A_TickCount
While !cancel && A_TickCount<(Start+time)
Sleep 10
}

Và cuối cùng là phần chạy auto, nó trông khá khác phần trước do thêm chức năng chạy auto với số lần xác định, nếu bạn muốn nó chạy luôn thì đặt là 0 ở ô số lần chạy, với cả mình có thêm phần gửi phím nữa. Phần gửi phím có hai chế độ SendInput và ControlSend.

Mã (Autohotkey):

RunAuto:
; Ngăn khi người dùng bấm thêm và ngưng khi chưa ghi thao tác
if playing or (LV_GetCount()=0)
return
Gui,Submit,Nohide
; CountTimes: ghi lại số lần lặp
CountTimes:=0
; index: ghi lại số dòng đã đọc của listview
index:=0
playing:=1
; Đặt times=-1, do vậy CountTimes không thể đạt tới vì thế vòng lặp ở dưới chạy liên tục
if (Times=0)
Times=-1
SB_SetText("Trạng thái: Đang chạy auto",1)
Loop
{
; Hết một lần chạy
if (index=LV_GetCount())
{
; Đọc lại số dòng từ đầu
index:=0
; Tăng số lần chạy
CountTimes++
}
; Do CountTimes ban đầu = 0 và nó sẽ +1 qua từng vòng lặp, nếu times=-1 thì vòng lặp sẽ chạy vô tận
if (Stop || CountTimes=Times)
break
; Sang dòng tiếp theo trong listview
index++
; Lấy dữ liệu từng dòng
Loop 7
LV_GetText(Data_%A_Index%,index,A_Index)
; Thay thế lệnh Sleep sẵn có do khi biến stop=0 thì vẫn phải đợi hết sleep mới dừng
Delay(Data_6,Stop)
if Stop
break
; Hạn chế lỗi khi người dùng thao tác chuột
SetControlDelay -1
ControlClick,x%Data_1% y%Data_2%,%Data_7%,,%Data_3%,,NA
; Bỏ qua khi không gửi phím
if !Data_4
continue
; gửi phím bằng ControlSend khi tick vào CheckBox
if Data_5
ControlSend,,% Data_4,% Data_7
; gửi chiếm màng hình, k chiếm bàn phím nhá
else
{
WinActivate,% Data_7
SendInput,{Blind}%Data_4%
}
}
stop:=0
playing:=0
SB_SetText("Trạng thái: Đã dừng auto",1)
return

Cuối cùng là đặt RequireAdmin() lên đầu để chạy lên hầu hết tất cả cửa sổ

Mã (Autohotkey):

RequireAdmin()

{
CommandLine := DllCall("GetCommandLine", "Str")

If !(A_IsAdmin || RegExMatch(CommandLine, " /restart(?!\S)")) {
Try {
If (A_IsCompiled) {
Run *RunAs "%A_ScriptFullPath%" /restart
} Else {
Run *RunAs "%A_AhkPath%" /restart "%A_ScriptFullPath%"
}
}
ExitApp
}
}

Dưới đây là code đầy đủ
***Nội dung ẩn không thể được trích dẫn.***Cuối cùng thân chào tất cả các bạn
Nhấp vào để mở rộng

like

lazyboy · 4/4/20

thanks bác

maunghua · 6/4/20

com men thi com men

bduyng · 7/4/20

rất bổ ích, cảm ơn bạn

TimCarter123 · 10/4/20

Cảm ơn bạn nhiều

thanhtu201196 · 11/4/20

tks

Người Đã Khuất · 14/4/20

thanks

nampro22 · 14/4/20

thanks bạn, mình đang cần ứng dụng này

Đăng nhập

Tải bản cài đặt AutoIT mới nhất

Quy định và nội quy

Hướng dẫn chèn mã AutoIT trong diễn đàn

AutoHotKey [Hướng dẫn] Cách tạo một auto click không chiếm chuột đơn giản

romanno1 Thành viên mới

1/6

congdv868 Thành viên mới

1/6

Nguyễn Tiến Vũ Thành viên mới

3/6

Cu_vo Thành viên mới

3/6

Yashiori Thành viên mới

1/6

anhemnhulz Thành viên mới

1/6

quachquesh Thành viên mới

1/6

thangcddtt Thành viên mới

1/6

thangdpybpro Thành viên mới

1/6

thangdpybpro Thành viên mới

1/6

thaiprovip Thành viên mới

1/6

nongminh Thành viên mới

1/6

thuonghttt Thành viên mới

1/6

lazyboy Thành viên mới

1/6

maunghua Thành viên mới

1/6

bduyng Thành viên mới

1/6

TimCarter123 Thành viên mới

1/6

thanhtu201196 Thành viên mới

1/6

Người Đã Khuất Thành viên mới

1/6

nampro22 Thành viên mới

1/6

Chia sẻ trang này

Đăng nhập

Tải bản cài đặt AutoIT mới nhất

Quy định và nội quy

Hướng dẫn chèn mã AutoIT trong diễn đàn

AutoHotKey [Hướng dẫn] Cách tạo một auto click không chiếm chuột đơn giản

Chia sẻ trang này

Tìm kiếm hữu ích