Hỏi đáp [Solved] Giúp đỡ tạo Button giả bằng Label, có hiệu ứng khi rê chuột vào

Tình hình là mình muốn dùng label để sử dụng thay thế cho nút button nhưng mình muốn khi để chuột lại label đó nó tự set màu khác cho label rồi khi bỏ ra nó để lại mặc định để cho nó có hiệu ứng màu mè thì phải làm thì phải làm sao :3
Giúp mình với :(

 

Cách đơn giản nhất là:
GUIgetCursorInfo, check nếu tọa độ của chuột vào label thì đổi màu.

 

mẫu cho bác nè :v

Mã (AutoIt):

#include "GUICtrlOnHover.au3"
#include <StaticConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiButton.au3>
#include <EditConstants.au3>

$Login = GUICreate("Login",349,172,-1,-1,$WS_POPUPWINDOW,-1)
_GuiRoundCorners($Login, 0, 0, 10, 10)
GUISetBkColor(0xfffffff,$Login)
$close=GUICtrlCreateLabel("×",295,0,56,22,BitOr($SS_CENTER,$SS_CENTERIMAGE),-1)
GUICtrlSetFont(-1,20,300,0,"Segoe UI Light")
GUICtrlSetBkColor(-1,"-2")
$an=GUICtrlCreateLabel("-",235,0,56,22,BitOr($SS_CENTER,$SS_CENTERIMAGE),-1)
GUICtrlSetFont(-1,26,300,0,"Segoe UI Light")
GUICtrlSetBkColor(-1,"-2")
$dangnhap=GUICtrlCreateLabel("Đăng nhập",250,120,90,30,BitOr($SS_CENTER,$SS_CENTERIMAGE),-1)
GUICtrlSetFont(-1,12,400,0,"Segoe UI")
GUICtrlSetColor(-1,"0xFFFFFF")
GUICtrlSetBkColor(-1,"0x16a085")
GUICtrlCreateInput("",150,40,180,29,-1,$WS_EX_CLIENTEDGE)
GUICtrlSetFont(-1,14,400,0,"Segoe UI")
GUICtrlCreateInput("",150,84,180,29,-1,$WS_EX_CLIENTEDGE)
GUICtrlSetFont(-1,14,400,0,"Segoe UI")
GUICtrlCreateLabel("Tên đăng nhập:",14,40,127,29,-1,-1)
GUICtrlSetFont(-1,14,400,0,"Segoe UI")
GUICtrlSetBkColor(-1,"-2")
GUICtrlCreateLabel("Mật khẩu:",43,84,98,29,-1,-1)
GUICtrlSetFont(-1,14,400,0,"Segoe UI")
GUICtrlSetBkColor(-1,"-2")
$dangki=GUICtrlCreateLabel("Đăng ký tài khoản",30,130,110,16,-1,-1)
GUICtrlSetFont(-1,9,400,0,"Segoe UI")
GUICtrlSetColor(-1,"0x95a5a6")
GUICtrlSetBkColor(-1,"-2")
_GUICtrl_OnHoverRegister($close,"flatclose1","flatclose2")
_GUICtrl_OnHoverRegister($an,"flatan1","flatan2")
_GUICtrl_OnHoverRegister($dangnhap,"flatlogin1","flatlogin2")
_GUICtrl_OnHoverRegister($dangki,"flatdangky1","flatdangky2")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $close
            Exit
        Case $an
            GUISetState(@SW_MINIMIZE)
    EndSwitch
WEnd
Func flatclose1()
    GUICtrlSetBkColor($close,0xFC4A4A)
    GUICtrlSetColor($close,0xFFFFFF)
EndFunc
Func flatclose2()
    GUICtrlSetBkColor($close,0xFFFFFF)
    GUICtrlSetColor($close,0x000000)
EndFunc
Func flatan1()
    GUICtrlSetBkColor($an,0xE5E5E9)
    GUICtrlSetColor($an,0xFFFFFF)
EndFunc
Func flatan2()
    GUICtrlSetBkColor($an,0xFFFFFF)
    GUICtrlSetColor($an,0x000000)
EndFunc
Func flatlogin1()
    GUICtrlSetBkColor($dangnhap,0x1abc9c)
    GUICtrlSetColor($dangnhap,0xFFFFFF)
EndFunc
Func flatlogin2()
    GUICtrlSetBkColor($dangnhap,0x16a085)
    GUICtrlSetColor($dangnhap,0xfffffff)
EndFunc
Func flatdangky1()
GUICtrlSetFont($dangki,9,400,4,"Segoe UI")
EndFunc
Func flatdangky2()
GUICtrlSetFont($dangki,9,400,0,"Segoe UI")
EndFunc
Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
   Dim $pos, $ret, $ret2
   $pos = WinGetPos($h_win)
   $ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $pos[2], "long", $pos[3], "long", $i_x3, "long", $i_y3)
   If $ret[0] Then
      $ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $ret[0], "int", 1)
      If $ret2[0] Then
         Return 1
      Else
         Return 0
      EndIf
   Else
      Return 0
   EndIf
EndFunc  ;==>_GuiRoundCorners